/* The linker command script */

/* Set the entry point */
ENTRY    (TaskEntryPoint)   


/* Set the memory mapping */
MEMORY 
{
   ROM_MAP (rx)   : ORIGIN = 0x00210000, LENGTH = 1600k
   RAM_MAP (!rx)  : ORIGIN = 0x0105F800, LENGTH = 128k
}

SECTIONS
{
   .text :
   {
      /* define the value of the begin of code section */
      PROVIDE(Image$$RO$$Base = .);
      *( .text ) 
      *( .rodata )
      /* define the value of the end of code section */
      PROVIDE(Image$$RO$$Limit = .);
      _etext = .;
   } > ROM_MAP

  .data : AT (_etext)
   {
      /* define the value of the begin of data initialised section */
      PROVIDE(Image$$RW$$Base = .);
      *( .data ) 
      /* define the value of the end of data initialised section */
      PROVIDE(Image$$RW$$Limit = .);
   } > RAM_MAP

   .bss :
   { 
      /* define the value of the begin of data zero initialised section */
      PROVIDE(Image$$ZI$$Base = .);
      *( .bss ) 
      *( COMMON ) 
      /* define the value of the end of data zero initialised section */
      PROVIDE(Image$$ZI$$Limit = .);
      PROVIDE(end = .);
   } > RAM_MAP
   
   . = ALIGN(4);
}

